Green Sky
0e1b1703f6
6ccc561a2ab Version 1.90.6 0d483a1c89f Backends: OpenGL3: Update loader for Linux to support EGL/GLVND. (#7562) 92df32d3390 Backends: OpenGL3: minor update of generated loader to match latest downloaded glcorearb.h/khrplatform.h files. 1ab1af80c74 Backends: Win32: Facepalm revert part of d15574c + additional commentary (#6275) d15574ce2a5 Backends: Win32: Removed silent return when calling ImGui_ImplWin32_WndProcHandler() with no active context! (#6275) d4495446d53 Windows, Internal: added experimental SkipRefresh mode. (#3515, #4763, #7556, #5116 , #4076, #2749, #2268) 0b309471f2e Windows: Changed default ClipRect to extend to windows' left and right borders. (#3312, #7540, #3756, #6170, #6365) 0c9c12c1bb9 InnerClipRect use ImFloor() matching docking branch (fix c41868531 for #6861, #2884, followed by rename 94da5842) 6ebbecc6a08 Realign assignments. fc4d818e170 Tables: Angled headers: added TableAngledHeadersTextAlign, ImGuiStyleVar_TableAngledHeadersTextAlign. (#6917) 4bb75671414 Tables: Angled headers: fixed multi-line label display when angle is flipped. (#6917) b30df8890de Table: Angled Headers: internal refactor to facilitate changing angled header bg and text colors per column. (#6917) 558c57a086c Fixed static analyzer warning "Pointer to local array 'overlay_buf' is stored outside the scope". Technically not used outside that scope, but best to play nice. 50b2ff0bf03 ImGuiIO: moved IMGUI_DISABLE_OBSOLETE_KEYIO block lower in the structure so other fields layout are not affected by it (#7534) 6ef4f67fa94 ImDrawList: moved cold fields lower in the structure so hot fields are closer to each others + better packed ImGuiNavItemData a60387a3c25 Backends: GLFW: Add define guards for glfw native defines. (#7536) 913151caa89 Demo: move progress bars to their own section. c895e987adf ProgressBar: added indeterminate mode by passing an animated negative value. (#5316, #5370, #1901) b8a44b198c9 TreeNode: added ImGuiTreeNodeFlags_SpanTextWidth. (#6937) baaaaea9e91 Demo: tweak TreeNode demo. da18fcb7aed Internals: ensure ButtonBehavior() is called with non 0 id. b720c0f541c Backends: Vulkan: Added convenience support for Volk via IMGUI_IMPL_VULKAN_USE_VOLK define. (#6582, #4854) 07e8ff9a8d4 Backends: Win32: Fixed a warning + moved header cruft below Changelog. fa0120ea5ea Windows: Fixed subsequent Begin() append calls from setting last item information for title-bar. (#7506, #823) 361432a0bb2 TreeNode: fixed layout so that TreeNode("") or TreeNode("##HiddenLabel") may properly be used with SameLine(0,0). (#7505, #282) eba46cb0d22 Drag and Drop: assert when nesting BeginDragDropSource() and BeginDragDropTarget() (#7504) + update Gallery links 9ec299ebe31 Backends: OpenGL: Detect ES3 contexts on desktop based on version string, (#7447) 7b8107e7c84 Examples: GLFW+WebGPU: Rename example_emscripten_wgpu/ to example_glfw_wgpu/ (#7435, #7132) 648278cd62f Examples: GLFW+WebGPU: Amends. (#7435, #7132) 80a5fdb1089 Examples: GLFW+WebGPU: Fixed condition for when to recreate swapchain. (#7435, #7132) f9df6bf6622 Examples: GLFW+WebGPU: added support for WebGPU-native/Dawn (#7435, #7132) git-subtree-dir: external/imgui/imgui git-subtree-split: 6ccc561a2ab497ad4ae6ee1dbd3b992ffada35cb
101 lines
3.3 KiB
CMake
101 lines
3.3 KiB
CMake
# Building for desktop (WebGPU-native) with Dawn:
|
|
# 1. git clone https://github.com/google/dawn dawn
|
|
# 2. cmake -B build -DIMGUI_DAWN_DIR=dawn
|
|
# 3. cmake --build build
|
|
# The resulting binary will be found at one of the following locations:
|
|
# * build/Debug/example_glfw_wgpu[.exe]
|
|
# * build/example_glfw_wgpu[.exe]
|
|
|
|
# Building for Emscripten:
|
|
# 1. Install Emscripten SDK following the instructions: https://emscripten.org/docs/getting_started/downloads.html
|
|
# 2. Install Ninja build system
|
|
# 3. emcmake cmake -G Ninja -B build
|
|
# 3. cmake --build build
|
|
# 4. emrun build/index.html
|
|
|
|
cmake_minimum_required(VERSION 3.10.2)
|
|
project(imgui_example_glfw_wgpu C CXX)
|
|
|
|
if(NOT CMAKE_BUILD_TYPE)
|
|
set(CMAKE_BUILD_TYPE Debug CACHE STRING "" FORCE)
|
|
endif()
|
|
|
|
set(CMAKE_CXX_STANDARD 17) # Dawn requires C++17
|
|
|
|
# Dear ImGui
|
|
set(IMGUI_DIR ../../)
|
|
|
|
# Libraries
|
|
if(EMSCRIPTEN)
|
|
set(LIBRARIES glfw)
|
|
add_compile_options(-sDISABLE_EXCEPTION_CATCHING=1 -DIMGUI_DISABLE_FILE_FUNCTIONS=1)
|
|
else()
|
|
# Dawn wgpu desktop
|
|
set(DAWN_FETCH_DEPENDENCIES ON)
|
|
set(IMGUI_DAWN_DIR CACHE PATH "Path to Dawn repository")
|
|
if (NOT IMGUI_DAWN_DIR)
|
|
message(FATAL_ERROR "Please specify the Dawn repository by setting IMGUI_DAWN_DIR")
|
|
endif()
|
|
|
|
option(DAWN_FETCH_DEPENDENCIES "Use fetch_dawn_dependencies.py as an alternative to using depot_tools" ON)
|
|
|
|
# Dawn builds many things by default - disable things we don't need
|
|
option(DAWN_BUILD_SAMPLES "Enables building Dawn's samples" OFF)
|
|
option(TINT_BUILD_CMD_TOOLS "Build the Tint command line tools" OFF)
|
|
option(TINT_BUILD_DOCS "Build documentation" OFF)
|
|
option(TINT_BUILD_TESTS "Build tests" OFF)
|
|
if (NOT APPLE)
|
|
option(TINT_BUILD_MSL_WRITER "Build the MSL output writer" OFF)
|
|
endif()
|
|
if(WIN32)
|
|
option(TINT_BUILD_SPV_READER "Build the SPIR-V input reader" OFF)
|
|
option(TINT_BUILD_WGSL_READER "Build the WGSL input reader" ON)
|
|
option(TINT_BUILD_GLSL_WRITER "Build the GLSL output writer" OFF)
|
|
option(TINT_BUILD_GLSL_VALIDATOR "Build the GLSL output validator" OFF)
|
|
option(TINT_BUILD_SPV_WRITER "Build the SPIR-V output writer" OFF)
|
|
option(TINT_BUILD_WGSL_WRITER "Build the WGSL output writer" ON)
|
|
endif()
|
|
|
|
add_subdirectory("${IMGUI_DAWN_DIR}" "${CMAKE_CURRENT_BINARY_DIR}/dawn" EXCLUDE_FROM_ALL)
|
|
|
|
set(LIBRARIES webgpu_dawn webgpu_cpp webgpu_glfw glfw)
|
|
endif()
|
|
|
|
add_executable(example_glfw_wgpu
|
|
main.cpp
|
|
# backend files
|
|
${IMGUI_DIR}/backends/imgui_impl_glfw.cpp
|
|
${IMGUI_DIR}/backends/imgui_impl_wgpu.cpp
|
|
# Dear ImGui files
|
|
${IMGUI_DIR}/imgui.cpp
|
|
${IMGUI_DIR}/imgui_draw.cpp
|
|
${IMGUI_DIR}/imgui_demo.cpp
|
|
${IMGUI_DIR}/imgui_tables.cpp
|
|
${IMGUI_DIR}/imgui_widgets.cpp
|
|
)
|
|
target_include_directories(example_glfw_wgpu PUBLIC
|
|
${IMGUI_DIR}
|
|
${IMGUI_DIR}/backends
|
|
)
|
|
|
|
target_link_libraries(example_glfw_wgpu PUBLIC ${LIBRARIES})
|
|
|
|
# Emscripten settings
|
|
if(EMSCRIPTEN)
|
|
target_link_options(example_glfw_wgpu PRIVATE
|
|
"-sUSE_WEBGPU=1"
|
|
"-sUSE_GLFW=3"
|
|
"-sWASM=1"
|
|
"-sALLOW_MEMORY_GROWTH=1"
|
|
"-sNO_EXIT_RUNTIME=0"
|
|
"-sASSERTIONS=1"
|
|
"-sDISABLE_EXCEPTION_CATCHING=1"
|
|
"-sNO_FILESYSTEM=1"
|
|
)
|
|
set_target_properties(example_glfw_wgpu PROPERTIES OUTPUT_NAME "index")
|
|
# copy our custom index.html to build directory
|
|
add_custom_command(TARGET example_glfw_wgpu POST_BUILD
|
|
COMMAND ${CMAKE_COMMAND} -E copy_if_different "${CMAKE_CURRENT_LIST_DIR}/web/index.html" $<TARGET_FILE_DIR:example_glfw_wgpu>
|
|
)
|
|
endif()
|